Rules for integrands of the form  (((d x))^m) (((a+b ArcSinh[c x]))^n)

1.  ∫(((d x))^m) (((a+b ArcSinh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫((((a+b ArcSinh[c x]))^n)/x)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: (1/x)==(1/b) Subst[Coth[-(a/b)+(x/b)],x,a+b ArcSinh[c x]] (∂_x)(a+b ArcSinh[c x])

Note: If  n∈(SuperPlus[ℤ]), then (x^n) Coth[-(a/b)+(x/b)] is integrable in closed-form.

Rule: If  n∈(SuperPlus[ℤ]), then

∫((((a+b ArcSinh[c x]))^n)/x)dx  ⟶  (1/b) Subst[∫(x^n) Coth[-(a/b)+(x/b)]dx,x,a+b ArcSinh[c x]]

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_./x_,x_Symbol] :=
  1/b*Subst[Int[x^n*Coth[-a/b+x/b],x],x,a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c},x] && IGtQ[n,0]

2:  ∫(((d x))^m)(((a+b ArcSinh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ m≠-1

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcSinh[c x]))^n)==((b c n (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))

Rule: If  n∈(SuperPlus[ℤ])∧ m≠-1, then

∫(((d x))^m)(((a+b ArcSinh[c x]))^n)dx  ⟶  (((((d x))^(m+1))(((a+b ArcSinh[c x]))^n))/(d(m+1)))-((b c n)/(d(m+1)))∫(((((d x))^(m+1))(((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(d_.*x_)^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcSinh[c*x])^n/(d*(m+1)) - 
  b*c*n/(d*(m+1))*Int[(d*x)^(m+1)*(a+b*ArcSinh[c*x])^(n-1)/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[n,0] && NeQ[m,-1]

2.  ∫(x^m) (((a+b ArcSinh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])

1:  ∫(x^m)(((a+b ArcSinh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n>0

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcSinh[c x]))^n)==((b c n (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))

Rule: If  n∈(SuperPlus[ℤ])∧ m≠-1, then

∫(x^m)(((a+b ArcSinh[c x]))^n)dx  ⟶  (((x^(m+1))(((a+b ArcSinh[c x]))^n))/(m+1))-((b c n)/(m+1))∫(((x^(m+1))(((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  x^(m+1)*(a+b*ArcSinh[c*x])^n/(m+1) - 
  b*c*n/(m+1)*Int[x^(m+1)*(a+b*ArcSinh[c*x])^(n-1)/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c},x] && IGtQ[m,0] && GtQ[n,0]

2.  ∫(x^m) (((a+b ArcSinh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n<-1

1:  ∫(x^m)(((a+b ArcSinh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ -2≤n<-1

Derivation: Integration by parts and integration by substitution

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Basis: (∂_x)((x^m) (Sqrt[1+(c^2) (x^2)]))==(((x^(m-1)) (m+(m+1) (c^2) (x^2)))/(Sqrt[1+(c^2) (x^2)]))

Basis: ((F[x])/(Sqrt[1+(c^2) (x^2)]))==(1/(b c)) Subst[F[((Sinh[-(a/b)+(x/b)])/c)],x,a+b ArcSinh[c x]] (∂_x)(a+b ArcSinh[c x])

Basis: If  m∈ℤ, then (((x^(m-1))(m+(m+1) (c^2) (x^2)))/(Sqrt[1+(c^2) (x^2)]))==(1/(b (c^m))) Subst[((Sinh[-(a/b)+(x/b)])^(m-1))(m+(m+1) ((Sinh[-(a/b)+(x/b)])^2)),x,a+b ArcSinh[c x]](∂_x)(a+b ArcSinh[c x])

Note: Although not essential, by switching to the hyperbolic trig world this rule saves numerous steps and results in more compact antiderivatives.

Rule: If  m∈(SuperPlus[ℤ])∧ -2≤n<-1, then

∫(x^m)(((a+b ArcSinh[c x]))^n)dx

  ⟶  (((x^m) (Sqrt[1+(c^2) (x^2)])(((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-(1/(b c(n+1)))∫(((x^(m-1)) (m+(m+1) (c^2) (x^2)) (((a+b ArcSinh[c x]))^(n+1)))/(Sqrt[1+(c^2) (x^2)]))dx

  ⟶  (((x^m) (Sqrt[1+(c^2) (x^2)])(((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-
(1/((b^2) (c^(m+1))(n+1)))Subst[∫(x^(n+1))((Sinh[-(a/b)+(x/b)])^(m-1)) (m+(m+1) ((Sinh[-(a/b)+(x/b)])^2))dx,x,a+b ArcSinh[c x]]

Program code:

Int[x_^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  x^m*Sqrt[1+c^2*x^2]*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  1/(b^2*c^(m+1)*(n+1))*
    Subst[Int[ExpandTrigReduce[x^(n+1),Sinh[-a/b+x/b]^(m-1)*(m+(m+1)*Sinh[-a/b+x/b]^2),x],x],x,a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c},x] && IGtQ[m,0] && GeQ[n,-2] && LtQ[n,-1]

2:  ∫(x^m) (((a+b ArcSinh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n<-2

Derivation: Integration by parts and algebraic expansion

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Basis: (∂_x)((x^m) (Sqrt[1+(c^2) (x^2)]))==((m (x^(m-1)))/(Sqrt[1+(c^2) (x^2)]))+(((c^2) (m+1) (x^(m+1)))/(Sqrt[1+(c^2) (x^2)]))

Rule: If  m∈(SuperPlus[ℤ])∧ n<-2, then

∫(x^m)(((a+b ArcSinh[c x]))^n)dx  ⟶  
(((x^m) (Sqrt[1+(c^2) (x^2)])(((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-
(m/(b c(n+1)))∫(((x^(m-1))(((a+b ArcSinh[c x]))^(n+1)))/(Sqrt[1+(c^2) (x^2)]))dx-((c(m+1))/(b (n+1)))∫(((x^(m+1))(((a+b ArcSinh[c x]))^(n+1)))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  x^m*Sqrt[1+c^2*x^2]*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  m/(b*c*(n+1))*Int[x^(m-1)*(a+b*ArcSinh[c*x])^(n+1)/Sqrt[1+c^2*x^2],x] - 
  c*(m+1)/(b*(n+1))*Int[x^(m+1)*(a+b*ArcSinh[c*x])^(n+1)/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c},x] && IGtQ[m,0] && LtQ[n,-2]

3:  ∫(x^m) (((a+b ArcSinh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==(1/(b c)) Subst[F[((Sinh[-(a/b)+(x/b)])/c)] Cosh[-(a/b)+(x/b)],x,a+b ArcSinh[c x]] (∂_x)(a+b ArcSinh[c x])

Note: If  m∈(SuperPlus[ℤ]), then (x^n) ((Sinh[-(a/b)+(x/b)])^m) Cosh[-(a/b)+(x/b)] is integrable in closed-form.

Rule: If  m∈(SuperPlus[ℤ]), then

∫(x^m) (((a+b ArcSinh[c x]))^n)dx  ⟶  (1/(b (c^(m+1)))) Subst[∫(x^n) ((Sinh[-(a/b)+(x/b)])^m) Cosh[-(a/b)+(x/b)]dx,x,a+b ArcSinh[c x]]

Program code:

Int[x_^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  1/(b*c^(m+1))*Subst[Int[x^n*Sinh[-a/b+x/b]^m*Cosh[-a/b+x/b],x],x,a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c,n},x] && IGtQ[m,0]

U:  ∫(((d x))^m) (((a+b ArcSinh[c x]))^n)dx

Rule:

∫(((d x))^m) (((a+b ArcSinh[c x]))^n)dx  ⟶  ∫(((d x))^m) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(d_.*x_)^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(d*x)^m*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,m,n},x]